[卡巴教程]自动激活 x 自动更新订阅 x 如何更优雅地使用测试版激活码-塞尔维亚世界杯-梅西世界杯进球数_中国进过世界杯吗

[卡巴教程]自动激活 x 自动更新订阅 x 如何更优雅地使用测试版激活码

查看: 69322|回复: 150

[卡巴教程]

自动激活 x 自动更新订阅 x 如何更优雅地使用测试版激活码

[复制链接]

n0b0dy

电梯直达

1楼

发表于 2025-4-23 07:21:10

|倒序浏览

|阅读模式

本帖最后由 n0b0dy 于 2025-4-23 15:12 编辑

前情提要：https://bbs.kafan.cn/thread-2267589-1-1.html

为什么要说“更”呢？

因为安装后不需要手动输入激活码激活，快到期时不需要手动更新授权许可，而是通过计划任务自动完成。仅适用于 64 位 Windows 系统，8.1 及以上，以及卡巴斯基针对家庭用户的安全产品。

以下是步骤：

0. 如果当前有安装卡巴斯基，请卸载，且不要保留授权许可

1. 将本文最后的代码保存为扩展名是 .bat 的批处理文件

2. 下载卡巴斯基官方安装程序，将其重命名为 startup.exe，并与上一步得到的 .bat 文件放置于同一文件夹

3. 运行 .bat

Screenshot 2025-04-23 005418.png (17.89 KB, 下载次数: 364)

下载附件

2025-4-23 06:56 上传

这里选择 "y"，才能更优雅地使用测试版激活码。如果不想多一个计划任务，就选择 "n"，回归手动

4. 选择想安装的产品

Screenshot 2025-04-23 010200.png (19.57 KB, 下载次数: 367)

下载附件

2025-4-23 07:02 上传

5. 坐和放宽，期间不要手贱，不要关闭出现的 cmd 窗口，只需等待安装完成

回头再补 FAQ

复活节过完了，这次没有彩蛋

@echo off

REM Set the current directory

cd /d "%~dp0"

REM Step 1: Get admin rights

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto :gotAdmin ) else ( powershell Start-Process '%0' -Verb runAs & exit /B )

:gotAdmin

REM Step 2: Get version information from startup.exe

setlocal EnableDelayedExpansion

for /f "usebackq delims=" %%i in (`powershell -command "& {(Get-Item '.\startup.exe').VersionInfo.ProductVersion}"`) do (

set "fullversion=%%i"

)

REM Extract just the first two segments (e.g., 21.20 from 21.20.8.505)

for /f "tokens=1,2 delims=." %%a in ("!fullversion!") do (

set "majorversion=%%a.%%b"

)

echo Detected Kaspersky version: !majorversion!

REM Step 3: Ask user to choose

:autoRenewal

echo.

echo Would you like to enable automatic license renewal?

set /p renewal="Enter your choice (y/n): "

if "%renewal%"=="y" (

goto :editionSelection

) else if "%renewal%"=="n" (

goto :installation

) else (

echo Invalid choice.

goto :autoRenewal

)

:editionSelection

echo.

echo Please select Kaspersky edition:

echo 1. Standard

echo 2. Plus

echo 3. Premium

echo.

set /p edition="Enter your choice (1-3): "

if "%edition%"=="1" (

set "editionName=Kaspersky Standard"

set "licenseKey=GAJPU-UTD18-3B2JJ-62CQ2"

) else if "%edition%"=="2" (

set "editionName=Kaspersky Plus"

set "licenseKey=GE86F-9WQRM-KK5PG-1ZE2W"

) else if "%edition%"=="3" (

set "editionName=Kaspersky Premium"

set "licenseKey=5AP55-UFAT1-QUMNN-7CUDZ"

) else (

echo Invalid choice.

goto :editionSelection

)

echo.

echo Selected edition: %editionName%

:installation

REM Step 4: Run "startup.exe" without self protection

echo.

echo Installing Kaspersky with self protection disabled...

start "" startup.exe /pSelfProtection=0

REM Step 5: Monitor registry key and modify values during installation

echo.

echo Monitoring and updating registry values...

:checkRegistry

REG QUERY "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" >nul 2>&1

if %errorlevel% equ 0 (

echo Registry found, applying modifications...

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" /t REG_SZ /d "" /f >nul 2>&1

echo Registry modifications completed.

goto :setupTask

) else (

goto :checkRegistry

)

:setupTask

if "%renewal%"=="n" (

goto :done

)

REM Step 6: Manage scheduled task for license renewal

:search

REM Clear previous value

set "avp="

REM Search for avp.com under Kaspersky Lab directory

for /f "delims=" %%A in ('dir /b /s /a-d "C:\Program Files (x86)\Kaspersky Lab\avp.com" 2^>nul') do (

set "avp=%%A"

)

if not defined avp (

timeout /t 5 >nul

goto :search

)

echo.

echo Found avp.com at: %avp%

echo Creating new license renewal task to run every 28 days...

set "taskname=Kaspersky License Renewal"

set "xmlfile=%TEMP%\task.xml"

REM Creating new license renewal task...

schtasks /create /tn "%taskname%" /tr "\"%avp%\" LICENSE /add %licenseKey%" /sc DAILY /mo 28 /f >nul 2>&1

REM Exporting the task to XML...

schtasks /query /tn "%taskname%" /xml > "%xmlfile%"

REM Modifying XML settings...

REM Use PowerShell to update XML

powershell -Command ^

"(Get-Content -Path '%xmlfile%') -replace 'false', 'true' |" ^

"ForEach-Object {$_ -replace 'true', 'false'} |" ^

"Set-Content -Path '%xmlfile%'" >nul 2>&1

REM Re-importing modified task...

schtasks /delete /tn "%taskname%" /f >nul 2>&1

schtasks /create /tn "%taskname%" /xml "%xmlfile%" /f >nul 2>&1

echo Task updated successfully.

echo.

echo Activating %editionName%...

:checkStartup

REM Check if avp.exe is running

tasklist | find /i "avp.exe" >nul 2>&1

if %errorlevel% neq 0 (

timeout /t 5 >nul 2>&1

goto :checkStartup

)

schtasks /run /tn "%taskname%"

echo.

echo Selected edition: %editionName%

echo Using version: %majorversion%

echo License key: %licenseKey%

:done

echo Process completed successfully.

endlocal

timeout /t 10复制代码

本主题由 Tarchia 于 2025-11-10 17:39 删除回复

评分

参与人数 9人气 +28

收起

理由

hipoxiaxxx

+ 3

冰柠橙夏

+ 5

版区有你更精彩：）

milolee

+ 3

版区有你更精彩：）

alan521

+ 2

版区有你更精彩：）

痞子潘

+ 3

查看全部评分

淘帖0

木子贝

来自 2楼

发表于 2025-7-8 09:37:36

FAQ：

1、官方在线安装包安装成功。

2、支持卡巴斯基标准版、加强版、优选版，不限版本号，不限语言

3、“自我保护”选项启用后，影响后续吗？作者答：不影响

4、需要保持关闭自我保护吗？还是说安装完就可以开启自我保护了，后续key也会自动更新？

大佬答：不需要。是的

群友答：不需要关闭自我保护，是通过

"C:\Program Files (x86)\Kaspersky Lab\Kaspersky 21.21\avp.com" LICENSE /add 5AP55-UFAT1-QUMNN-7CUDZ这个带参数的命令行来续费授权，也可以用CMD命令来运行这个带参数的命令

4、问题：用代码安装激活后，提前使用计划任务更新激活码后不久就会出现“应用程序的完整性已被破坏”的提示 ...

大佬答：

这是修改文件后，软件自检效验不过引起的

这就是原因，跟计划任务没有关系。

其实在安装期间修改注册表这个动作就是在打时间差，在卡巴开启完整性检查前完成修改，这个间隙很短暂。我猜是你电脑性能太强，打时间差失败。

我只能建议你重新试一次。可以的话，在安装过程中想办法拖慢系统。

n0b0dy

来自 3楼

楼主|

发表于 2025-9-27 03:33:31

本帖最后由 n0b0dy 于 2025-9-27 03:35 编辑

# Changelog

## 2025-09-26

### Changed

- 以低 CPU 优先级运行 startup.exe，希望能避免破坏应用程序完整性

(我觉得还没失效，如果你觉得失效了，就不要用了）

## 2025-05-26

### Changed

- 优化了计划任务的运行条件：

- 在使用电池的情况下也可运行计划任务

- 仅在连接网络时运行计划任务

- 若错过预定运行时间，计划任务将在系统下一次登录后补运行

@echo off

REM Set the current directory

cd /d "%~dp0"

REM Step 1: Get admin rights

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto :gotAdmin ) else ( powershell Start-Process '%0' -Verb runAs & exit /B )

:gotAdmin

REM Step 2: Get version information from startup.exe

setlocal EnableDelayedExpansion

for /f "usebackq delims=" %%i in (`powershell -command "& {(Get-Item '.\startup.exe').VersionInfo.ProductVersion}"`) do (

set "fullversion=%%i"

)

REM Extract just the first two segments (e.g., 21.20 from 21.20.8.505)

for /f "tokens=1,2 delims=." %%a in ("!fullversion!") do (

set "majorversion=%%a.%%b"

)

echo Detected Kaspersky version: !majorversion!

REM Step 3: Ask user to choose

:autoRenewal

echo.

echo Would you like to enable automatic license renewal?

set /p renewal="Enter your choice (y/n): "

if "%renewal%"=="y" (

goto :editionSelection

) else if "%renewal%"=="n" (

goto :installation

) else (

echo Invalid choice.

goto :autoRenewal

)

:editionSelection

echo.

echo Please select Kaspersky edition:

echo 1. Standard

echo 2. Plus

echo 3. Premium

echo.

set /p edition="Enter your choice (1-3): "

if "%edition%"=="1" (

set "editionName=Kaspersky Standard"

set "licenseKey=GAJPU-UTD18-3B2JJ-62CQ2"

) else if "%edition%"=="2" (

set "editionName=Kaspersky Plus"

set "licenseKey=GE86F-9WQRM-KK5PG-1ZE2W"

) else if "%edition%"=="3" (

set "editionName=Kaspersky Premium"

set "licenseKey=5AP55-UFAT1-QUMNN-7CUDZ"

) else (

echo Invalid choice.

goto :editionSelection

)

echo.

echo Selected edition: %editionName%

:installation

REM Step 4: Run "startup.exe" without self protection

echo.

echo Installing Kaspersky with self protection disabled...

start "" /low startup.exe /pSelfProtection=0

REM Step 5: Monitor registry key and modify values during installation

echo.

echo Monitoring and updating registry values...

:checkRegistry

REG QUERY "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" >nul 2>&1

if %errorlevel% equ 0 (

echo Registry found, applying modifications...

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" /t REG_SZ /d "" /f >nul 2>&1

echo Registry modifications completed.

goto :setupTask

) else (

goto :checkRegistry

)

:setupTask

if "%renewal%"=="n" (

goto :done

)

REM Step 6: Manage scheduled task for license renewal

:search

REM Clear previous value

set "avp="

REM Search for avp.com under Kaspersky Lab directory

for /f "delims=" %%A in ('dir /b /s /a-d "C:\Program Files (x86)\Kaspersky Lab\avp.com" 2^>nul') do (

set "avp=%%A"

)

if not defined avp (

timeout /t 5 >nul

goto :search

)

echo.

echo Found avp.com at: %avp%

echo Creating new license renewal task to run every 28 days...

set "taskname=Kaspersky License Renewal"

set "xmlfile=%TEMP%\task.xml"

REM Creating new license renewal task...

schtasks /create /tn "%taskname%" /tr "\"%avp%\" LICENSE /add %licenseKey%" /sc DAILY /mo 28 /f >nul 2>&1

REM Exporting the task to XML...

schtasks /query /tn "%taskname%" /xml > "%xmlfile%"

REM Modifying XML settings...

REM Use PowerShell to update XML

powershell -Command ^

"$xml = [xml](Get-Content '%xmlfile%');" ^

"$nsmgr = New-Object System.Xml.XmlNamespaceManager($xml.NameTable);" ^

"$nsmgr.AddNamespace('ns', $xml.DocumentElement.NamespaceURI);" ^

"$settings = $xml.SelectSingleNode('//ns:Settings', $nsmgr);" ^

"if (-not $settings) { $settings = $xml.CreateElement('Settings', $xml.DocumentElement.NamespaceURI); $xml.Task.AppendChild($settings) | Out-Null };" ^

"if (-not $settings.SelectSingleNode('ns:StartWhenAvailable', $nsmgr)) {" ^

"$node = $xml.CreateElement('StartWhenAvailable', $xml.DocumentElement.NamespaceURI);" ^

"$node.InnerText = 'true'; $settings.AppendChild($node) | Out-Null" ^

"} else { $settings.SelectSingleNode('ns:StartWhenAvailable', $nsmgr).InnerText = 'true' };" ^

"if (-not $settings.SelectSingleNode('ns:DisallowStartIfOnBatteries', $nsmgr)) {" ^

"$node = $xml.CreateElement('DisallowStartIfOnBatteries', $xml.DocumentElement.NamespaceURI);" ^

"$node.InnerText = 'false'; $settings.AppendChild($node) | Out-Null" ^

"} else { $settings.SelectSingleNode('ns:DisallowStartIfOnBatteries', $nsmgr).InnerText = 'false' };" ^

"if (-not $settings.SelectSingleNode('ns:RunOnlyIfNetworkAvailable', $nsmgr)) {" ^

"$node = $xml.CreateElement('RunOnlyIfNetworkAvailable', $xml.DocumentElement.NamespaceURI);" ^

"$node.InnerText = 'true'; $settings.AppendChild($node) | Out-Null" ^

"} else { $settings.SelectSingleNode('ns:RunOnlyIfNetworkAvailable', $nsmgr).InnerText = 'true' };" ^

"$xml.Save('%xmlfile%')" >nul 2>&1

REM Re-importing modified task...

schtasks /delete /tn "%taskname%" /f >nul 2>&1

schtasks /create /tn "%taskname%" /xml "%xmlfile%" /f >nul 2>&1

del "%xmlfile%" 2>nul

echo Task updated successfully.

echo.

echo Activating %editionName%...

:checkStartup

REM Check if avp.exe is running

tasklist | find /i "avp.exe" >nul 2>&1

if %errorlevel% neq 0 (

timeout /t 5 >nul 2>&1

goto :checkStartup

)

schtasks /run /tn "%taskname%"

echo.

echo Selected edition: %editionName%

echo Using version: %majorversion%

echo License key: %licenseKey%

:done

echo Process completed successfully.

endlocal

timeout /t 10复制代码

fangxiang

4楼

发表于 2025-4-23 07:51:11

本帖最后由 fangxiang 于 2025-7-21 21:24 编辑

使用中！非常棒！大爱无疆呀。

huawei_518

5楼

发表于 2025-4-23 08:41:31

本帖最后由 huawei_518 于 2025-4-24 12:45 编辑

感谢分享，对于中文版，英文小白，我顺便翻译下.将代码复制到记事本打开，点另存为，将编码改成ANSI后保存为.bat文件即可.

@echo off

REM 设置当前目录

cd /d "%~dp0"

REM 步骤1：获取管理员权限

NET FILE 1>NUL 2>NUL

if '%errorlevel%' == '0' ( goto :gotAdmin ) else ( powershell Start-Process '%0' -Verb runAs & exit /B )

:gotAdmin

REM 步骤2：从startup.exe获取版本信息

setlocal EnableDelayedExpansion

for /f "usebackq delims=" %%i in (`powershell -command "& {(Get-Item '.\startup.exe').VersionInfo.ProductVersion}"`) do (

set "fullversion=%%i"

)

REM 提取前两个版本段（例如从21.20.8.505提取21.20）

for /f "tokens=1,2 delims=." %%a in ("!fullversion!") do (

set "majorversion=%%a.%%b"

)

echo 检测到卡巴斯基版本: !majorversion!

REM 步骤3：用户选择环节

:autoRenewal

echo.

echo 是否启用许可证自动续期？

set /p renewal="请输入选择（y/n）: "

if /i "%renewal%"=="y" (

goto :editionSelection

) else if /i "%renewal%"=="n" (

goto :installation

) else (

echo 无效选择

goto :autoRenewal

)

:editionSelection

echo.

echo 请选择卡巴斯基版本：

echo 1. 标准版

echo 2. 加强版

echo 3. 优选版

echo.

set /p edition="请输入选择（1-3）: "

if "%edition%"=="1" (

set "editionName=卡巴斯基标准版"

set "licenseKey=GAJPU-UTD18-3B2JJ-62CQ2"

) else if "%edition%"=="2" (

set "editionName=卡巴斯基加强版"

set "licenseKey=GE86F-9WQRM-KK5PG-1ZE2W"

) else if "%edition%"=="3" (

set "editionName=卡巴斯基优选版"

set "licenseKey=5AP55-UFAT1-QUMNN-7CUDZ"

) else (

echo 无效选择

goto :editionSelection

)

echo.

echo 已选版本：%editionName%

:installation

REM 步骤4：禁用自我保护运行startup.exe

echo.

echo 正在禁用自我保护安装卡巴斯基...

start "" startup.exe /pSelfProtection=0

if %errorlevel% neq 0 (

echo 启动 startup.exe 失败

goto :done

)

REM 步骤5：安装过程中监控并修改注册表值

echo.

echo 正在监控并更新注册表值...

:checkRegistry

REG QUERY "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" >nul 2>&1

if %errorlevel% equ 0 (

echo 找到注册表项，正在应用修改...

REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\KasperskyLab\AVP%majorversion%\environment" /v "ProductStatus" /t REG_SZ /d "" /f >nul 2>&1

if %errorlevel% neq 0 (

echo 注册表修改失败

goto :done

)

echo 注册表修改完成

goto :setupTask

) else (

ping -n 2 127.0.0.1 >nul 2>&1

goto :checkRegistry

)

:setupTask

if /i "%renewal%"=="n" (

goto :done

)

REM 步骤6：管理许可证续期的计划任务

:search

REM 清除之前的值

set "avp="

REM 在卡巴斯基软件目录下搜索avp.com

for /f "delims=" %%A in ('dir /b /s /a-d "C:\Program Files (x86)\Kaspersky Lab\avp.com" 2^>nul') do (

set "avp=%%A"

)

if not defined avp (

timeout /t 5 >nul

goto :search

)

echo.

echo 已在以下路径找到avp.com：%avp%

echo 正在创建每28天运行一次的许可证续期任务...

set "taskname=卡巴斯基许可证续期"

set "xmlfile=%TEMP%\task.xml"

REM 创建新的许可证续期任务...

schtasks /create /tn "%taskname%" /tr "\"%avp%\" LICENSE /add %licenseKey%" /sc DAILY /mo 28 /f >nul 2>&1

if %errorlevel% neq 0 (

echo 创建计划任务失败

goto :done

)

REM 将任务导出为XML...

schtasks /query /tn "%taskname%" /xml > "%xmlfile%"

if %errorlevel% neq 0 (

echo 导出计划任务XML失败

goto :done

)

REM 修改XML设置...

REM 使用PowerShell更新XML

powershell -Command ^

"(Get-Content -Path '%xmlfile%') -replace 'false', 'true' |" ^

"ForEach-Object {$_ -replace 'true', 'false'} |" ^

"Set-Content -Path '%xmlfile%'" >nul 2>&1

if %errorlevel% neq 0 (

echo 修改计划任务XML失败

goto :done

)

REM 重新导入修改后的任务...

schtasks /delete /tn "%taskname%" /f >nul 2>&1

schtasks /create /tn "%taskname%" /xml "%xmlfile%" /f >nul 2>&1

if %errorlevel% neq 0 (

echo 重新导入计划任务失败

goto :done

)

echo 任务更新成功

echo.

echo 正在激活%editionName%...

:checkStartup

REM 检查avp.exe是否运行

tasklist | find /i "avp.exe" >nul 2>&1

if %errorlevel% neq 0 (

timeout /t 5 >nul 2>&1

goto :checkStartup

)

schtasks /run /tn "%taskname%"

echo.

echo 已选版本：%editionName%

echo 使用版本：%majorversion%

echo 许可证密钥：%licenseKey%

:done

echo 处理成功完成

endlocal

timeout /t 10 复制代码

评分

参与人数 4人气 +11

收起

理由

alan521

+ 3

版区有你更精彩：）

冰柠橙夏

+ 3

赞一个!

月落、点星灯

+ 2

版区有你更精彩：）

n0b0dy

+ 3

感谢翻译

查看全部评分

yanjun198201

6楼

发表于 2025-4-23 08:58:42

请问支持什么版本的卡巴软件？中英文都可以吗？

metaverse

7楼

发表于 2025-4-23 09:01:15

本帖最后由 metaverse 于 2025-4-23 09:36 编辑

感谢分享，赶紧靠近两位大佬，请问一下如果是91天的试用期只需要修改第109行的28数字吗？想改成89天

Wama

8楼

发表于 2025-4-23 09:05:04

感谢分享，又省力了

xtmatao

9楼

发表于 2025-4-23 09:59:57

本帖最后由 xtmatao 于 2025-4-23 10:44 编辑

第一时间尝鲜安装测试

使用https://bbs.kafan.cn/thread-2280898-1-1.html这个帖子的21.21

安装中选择 y ,中途cmd退出，之后安装完成，跳出输入激活码界面,并没有自动完成，是不支持该版本吗

抱歉，应该看到了，代码中指定版本号了修改版本号为新版也不能通过，测试失败

请大佬有空指点一下，还要修改啥？

继续测试21.20，一样的结果，安装完成仍然需要手动输入激活码，并没有自动完成

wsasecy

10楼

发表于 2025-4-23 10:26:39

我只想说‘好’

飞飞鱼

11楼

发表于 2025-4-23 10:32:29

本帖最后由飞飞鱼于 2025-4-23 10:51 编辑

第二部选择的时候选择了加强版，但是最后安装的还是标准版，激活码确实不用自己输入。

xtmatao

12楼

发表于 2025-4-23 11:00:37

飞飞鱼发表于 2025-4-23 10:32

第二部选择的时候选择了加强版，但是最后安装的还是标准版，激活码确实不用自己输入。

这边测试下来，安装完成仍然要输入激活码？用的是在线安装包，

gdg2000

13楼

发表于 2025-4-23 11:03:44

21.21 失败不能试用循环退回21.20可以了不知啥原因

xtmatao

14楼

发表于 2025-4-23 11:11:11

gdg2000 发表于 2025-4-23 11:03

21.21 失败不能试用循环退回21.20可以了不知啥原因

你是用在线安装包还是离线安装包，这边安装21.20在线安装包失败，不能自动输入激活码

xtmatao

15楼

发表于 2025-4-23 11:13:24

huawei_518 发表于 2025-4-23 08:41

感谢分享，对于中文版，英文小白，我顺便翻译下.

感谢分享

大佬这段代码，保存为BAT，运行报错，跑不起来

duguqiuai006

16楼

发表于 2025-4-23 14:08:01

xtmatao 发表于 2025-4-23 09:59

第一时间尝鲜安装测试

使用https://bbs.kafan.cn/thread-2280898-1-1.html这个帖子的21.21

安装中选择 y ...

已经测试21.21了啊

n0b0dy

17楼

楼主|

发表于 2025-4-23 15:20:16

由于卡饭的文本编辑器中存在转义字符 bug，导致代码第 109 行缺少必须的字符。现已修复。我在这里跟已经测试的朋友说一声抱歉。

@huawei_518 感谢翻译，还得麻烦你修改一下第 109 行

huawei_518

18楼

发表于 2025-4-23 15:35:11

n0b0dy 发表于 2025-4-23 15:20

由于卡饭的文本编辑器中存在转义字符 bug，导致代码第 109 行缺少必须的字符。现已修复。我在这里跟已经测 ...

好的，我也没注意，已修改.

huawei_518

19楼

发表于 2025-4-23 15:35:52

xtmatao 发表于 2025-4-23 11:13

感谢分享

大佬这段代码，保存为BAT，运行报错，跑不起来

已修复

xiexin0910

20楼

发表于 2025-4-23 17:51:06

我安装以失败告终

n0b0dy

21楼

楼主|

发表于 2025-4-23 18:41:25

yanjun198201 发表于 2025-4-23 08:58

请问支持什么版本的卡巴软件？中英文都可以吗？

支持卡巴斯基标准版、加强版、优选版，不限版本号，不限语言

n0b0dy

22楼

楼主|

发表于 2025-4-23 18:44:07

metaverse 发表于 2025-4-23 09:01

感谢分享，赶紧靠近两位大佬，请问一下如果是91天的试用期只需要修改第109行的28数字吗？想改成89天

没错，就是修改那里。

另外 109 行有修改，之前有两个字符被吞了。你需要重新复制代码

n0b0dy

23楼

楼主|

发表于 2025-4-23 18:45:40

xtmatao 发表于 2025-4-23 09:59

第一时间尝鲜安装测试

使用https://bbs.kafan.cn/thread-2280898-1-1.html这个帖子的21.21

安装中选择 y ...

抱歉，之前代码 109 行有两个字符被吞了，现已修复。

可以的话，请再试一次

n0b0dy

24楼

楼主|

发表于 2025-4-23 18:47:39

飞飞鱼发表于 2025-4-23 10:32

第二部选择的时候选择了加强版，但是最后安装的还是标准版，激活码确实不用自己输入。

抱歉，之前代码 109 行有两个字符被吞了，导致没有正确创建计划任务，现已修复。

可以的话，请再试一次

n0b0dy

25楼

楼主|

发表于 2025-4-25 02:56:21

haibovip 发表于 2025-4-24 09:45

感谢大佬分享，已经安装成功，

最后一个问题：“自我保护”选项启用后，影响后续吗？

不影响

n0b0dy

26楼

楼主|

发表于 2025-4-25 03:00:01

Wama 发表于 2025-4-24 11:26

有一个bug，选择renewal为no的时候，不会在安装的时候自动激活，还需要手动输入激活码。理想情况是，选择re ...

不是 bug，是 feature

你的建议挺好，但是现实很骨感，我不打算采纳 XD

n0b0dy

27楼

楼主|

发表于 2025-4-25 03:01:21

meiveryq 发表于 2025-4-24 17:48

需要保持关闭自我保护吗？还是说安装完就可以开启自我保护了，后续key也会自动更新？

不需要

是的

n0b0dy

28楼

楼主|

发表于 2025-4-25 03:10:51

本帖最后由 n0b0dy 于 2025-4-25 03:15 编辑

我是风我是风发表于 2025-4-24 21:21

@n0b0dy 用代码安装激活后，提前使用计划任务更新激活码后不久就会出现“应用程序的完整性已被破坏”的提示 ...

这是修改文件后，软件自检效验不过引起的

这就是原因，跟计划任务没有关系。

其实在安装期间修改注册表这个动作就是在打时间差，在卡巴开启完整性检查前完成修改，这个间隙很短暂。我猜是你电脑性能太强，打时间差失败。

我只能建议你重新试一次。可以的话，在安装过程中想办法拖慢系统。

[分享]你应该怎么洗自定义，史诗自定义洗词条前瞻
逸名在线字典："渭字的含义、左边一个三点水，右边一个胃字、渭字的笔划、渭字的意义、渭字的解释、渭字的粤语发音